############################################################## 
############################################################## 
############################################################## OLD STYLE MAGIC
############################################################## 
############################################################## 

mse version: 0.3.4
game: magic
short name: Old style
full name: Before 8th edition
icon: card-sample.png
position hint: 101

card width: 337
card height: 469
card dpi: 134.98

############################################################## Extra scripts
## COPY/PASTE from magic-new.mse-style/style

init script:
	# Use the normal tap symbol
	mana_t := {
		if      styling.tap_symbol == "old"        then "old"
		else if styling.tap_symbol == "diagonal T" then "older"
		else                                            "new"
	}
	# Use guild mana symbols?
	guild_mana := { styling.use_guild_mana_symbols }
	
	# Only white cards use a black font
	font_colors_white := { input != "w" }
	
	# Alpha style lands?  Different blending for multicolored lands.
	#Did it this way because was getting longer other way, due to redefining color_background parts.
	color_combination := {
		# The base hybrid, without the outer frame blended over it
		base := base_hybrid[shape][color_count]()
		
		# Put a frame around it?
		if type == "card" and land and color_count == 2 and shape != "overlay" and styling.alpha_style_blending then
			masked_blend(
				mask:  "alpha_blend.png",
				dark:  land_template(colors[0]),
				light: land_template(colors[1]),
			)
		else if land then
			masked_blend(
				mask:  "land_blend_{type}.png",
				dark:  land_template("c"),
				light: base,
			)
		else if multi then 
			masked_blend(
				mask: ( if styling.type_of_gradient_multicolor == "full card" then "multicolor_blend_{type}.png"
					else if styling.type_of_gradient_multicolor == "trim only" then "multicolor_blend_{type}2.png"
					else "multicolor_blend_{type}.png" ),
				dark:  template("m"),
				light: base,
			)
		else if artifact then 
			masked_blend(
				mask:  "multicolor_blend_{type}.png",
				dark:  template("a"),
				light: base,
			)
		else if color_count > 1 and mask_hybrid_with_land() then
			masked_blend(
				mask:  "hybrid_blend_{type}.png",
				dark:  land_template("c"),
				light: base,
			)
		else base
	}

############################################################## Set info fields
set info style:
	symbol:
		variation:
			name: olduncommon
			border radius: 0.10
			fill type: linear gradient
			fill color 1:   rgb(224,224,224)
			fill color 2:   rgb(84, 84, 84)
			border color 1: rgb(255,255,255)
			border color 2: rgb(255,255,255)
		variation:
			name: oldrare
			border radius: 0.10
			fill type: linear gradient
			fill color 1:   rgb(214,196,94)
			fill color 2:   rgb(95, 84, 40)
			border color 1: rgb(255,255,255)
			border color 2: rgb(255,255,255)

############################################################## Extra style options

styling field:
	type: boolean
	name: use guild mana symbols
	description: Use the Ravnica guild symbols instead of the official half/half circles for hybrid mana.
	initial: no
styling field:
	type: boolean
	name: popup mana symbols
	description: Use the symbols of the casting cost line inside the text box as well
	initial: no
styling field:
	type: boolean
	name: alpha style blending
	description: Use Alpha-style dual blending
	initial: no
styling field:
	type: choice
	name: type of gradient multicolor
	description: What parts of the card should be blended for gradient multicolor?
	choice: full card
	choice: trim only
	initial: full card
styling field:
	type: choice
	name: tap symbol
	description: What tap symbol should be used on cards?
	initial: old
	choice: modern
	choice: old
	choice: diagonal T
styling field:
	type: choice
	name: center text
	description: When to center text (short text only means only on one-line cards with no flavor text)
	choice: always
	choice: short text only
	choice: never
	initial: never
styling field:
	type: boolean
	name: colored rarities
	description: Should rarity symbols be different colors, such as gold, silver, and purple?
	initial: yes
styling style:
	use guild mana symbols:
		choice images:
			yes: /magic-mana-small.mse-symbol-font/mana_guild_rg.png
			no:  /magic-mana-small.mse-symbol-font/mana_rg.png
	popup mana symbols:
		choice images:
			yes: /magic-mana-large.mse-symbol-font/mana_w.png
			no:  /magic-mana-small.mse-symbol-font/mana_w.png
	tap symbol:
		render style: both
		choice images:
			modern:     /magic-mana-large.mse-symbol-font/mana_t.png
			old:        /magic-mana-large.mse-symbol-font/mana_t_old.png
			diagonal T: /magic-mana-large.mse-symbol-font/mana_t_older.png

############################################################## Card fields
card style:
	############################# Background stuff
	border color:
		left: 0
		top : 0
		width:	337
		height:	468
		radius: 18
		left width:   18
		right width:  19
		top width:    18
		bottom width: 19
		z index: -1
	card color:
		left:	12
		top:	12
		width:	312
		height:	444
		z index: -2
		render style: image
		popup style: in place
		image: { card_background() }

	############################# Name line
	name:
		left: 39
		top : 21
		right: { 300 - card_style.casting_cost.content_width }
		height: 22
		alignment: bottom shrink-overflow
		padding bottom: 0
		z index: 1
		font:
			name: MagicMedieval
			size: 14
			color: rgb(255,255,255)
			shadow color: rgb(0,0,0)
			shadow displacement x: 1
			shadow displacement y: 1
	casting cost:
		right: 304
		top : 21
		width: { max(30, card_style.casting_cost.content_width) + 5 }
		height: 22
		alignment: middle right
		symbol font:
			name: magic-mana-small
			size: 14
			alignment: middle right
		always symbol: true
		z index: 2
		padding top: 0
	card symbol:
		left: 22
		top : 21
		height: 20
		width: 14
		render style: image
		choice images:
			tombstone: tombstone.png

	############################# Image
	image:
		left:	41
		top:	47
		width:	255
		height:	207
		z index: 1

	############################# Card type

	type:
		left: 37
		top : 260
		width: 240
		height: 18
		alignment: top left shrink-overflow
		z index: 1
		font:
			name: MPlantin
			size: 11
			color: rgb(255,255,255)
			shadow color: rgb(0,0,0)
			shadow displacement x: 1
			shadow displacement y: 1
			separator color: rgb(192,192,192)

	rarity:
		left: 277
		top : 257
		width: 22
		height: 22
		z index: 1
		render style: image
		choice images:
			# Images based on the set symbol
			basic land: script: symbol_variation(symbol: set.symbol, variation: "common")
			common:     script: symbol_variation(symbol: set.symbol, variation: "common")
			uncommon:
				script:
					if styling.colored_rarities
					then symbol_variation(symbol: set.symbol, variation: "olduncommon")
					else symbol_variation(symbol: set.symbol, variation: "common")
			rare:
				script:
					if styling.colored_rarities
					then symbol_variation(symbol: set.symbol, variation: "oldrare")
					else symbol_variation(symbol: set.symbol, variation: "common")
			special:
				script:
					if styling.colored_rarities
					then symbol_variation(symbol: set.symbol, variation: "special")
					else symbol_variation(symbol: set.symbol, variation: "common")

	############################# Text box
	text:
		left: 43
		top : 283
		width: 253
		height: 128
		font:
			name: MPlantin
			italic name: MPlantin-Italic
			size: 13
			scale down to: 6
			color: rgb(0,0,0)
		symbol font:
			name:
				script:
					if styling.popup_mana_symbols
					then "magic-mana-large"
					else "magic-mana-small"
			size: 13
		alignment:
			script:
				if (styling.center_text == "short text only" and
				   not contains(match:"\n", card.rule_text) and
				   card.flavor_text == "<i-flavor></i-flavor>" and
				   card_style.text.content_lines <= 2) or
				   styling.center_text == "always"
				then "middle center"
				else "middle left"
		z index: 2
		padding left:   2
		padding top:    2
		padding right:  2
		padding bottom: 2
		line height hard: 1.2
		line height line: 1.5
		line height soft: 0.9
	watermark:
		left: 111
		top : 277
		width: 124
		height: 140
		z index: 1
		render style: image
		alignment: middle center
		include file: magic-watermarks.mse-include/watermarks

	############################# PT
	pt:
		z index: 4
		left:	266
		top:	420
		width:	42
		height:	28
		alignment: right top
		font:
			name: Mplantin
			size: 16
			weight: bold
			color: rgb(255,255,255)
			shadow color: rgb(0,0,0)
			shadow displacement x: 2
			shadow displacement y: 2
			separator color: rgb(255,50,50)

	############################# Card sorting / numbering
	############################# Copyright stuff

	illustrator:
		left: 68
		top : 419
		width: 200
		height: 14
		z index: 1
		alignment: center
		font:
			name: Mplantin
			size: 9
			color: rgb(255,255,255)
			shadow color: rgb(0,0,0)
			shadow displacement x: 1
			shadow displacement y: 1

	copyright line:
		left: 68
		top : 434
		width: 200
		height: 9
		z index: 1
		alignment: center
		font:
			name: MPlantin
			size: 6
			color: { font_color(card.card_color) }
